ip-adressen anzeigen

hallo,

gibt es einen befehl, mit dem man die statischen ip-adressen und computernamen in einem netz auflisten kann?

Bettina L.

 

hi!

yo mit net view kannst du alle pcs im netz anzeigen lassen

und mit ping die einzelnen namen anpingen, ipadressen werden angezeigt


ich hoffe es stimmt und konnte dir dadurch helfen

lg ninjinjetlee
es ist verdammt hart der beschte zu sein

 

kannst meine whos.bat haben; musst aber in der vorletzten zeile deine eigenen Computernamen eintragen:

Code:

@echo off
if %1.==. goto loop

:ping
rem ****  Absetzen des Pings  ****
ping -n 1 -a %1 > %temp%\whoserg1.tmp

rem ****  Online?  ****
find "berschreitung der Anforderung." %temp%\whoserg1.tmp > %temp%\whoserg2.tmp
find "Unbekannter Host" %temp%\whoserg1.tmp >> %temp%\whoserg2.tmp
for %%i in (%temp%\whoserg2.tmp) do set Size=%%~zi
if %Size% GTR 70 goto nein

rem **** Ja  ****
find "mit 32 Bytes Daten:" %temp%\whoserg1.tmp > %temp%\whoserg3.tmp
for /F "skip=2 tokens=2,3*" %%n in (%temp%\whoserg3.tmp) do set Compy="%%n %%o"
set Compy=%Compy:~1%
set Compy=%Compy:~0,-1%
echo %Compy%
echo                                   online
echo.
goto cleanup

rem ****  Nein  ****
:nein
echo %1 [unbekannt]
echo                                  offline
echo.

rem ****  Umgebunsvariablen und .tmp-Files löschen  ****
:cleanup
set Compy=
set Size=
rem del %temp%\whoserg1.tmp
rem del %temp%\whoserg2.tmp
rem del %temp%\whoserg3.tmp
goto ende

rem ****  Hauptprogramm // nur ausgeführt wenn keine parameter übergeben  ****
:loop
for %%l in (router mailserver monolith jane-in-the-box dodger fast-jack) do call %0 %%l

:ende

ergebnis sieht so aus:

Code:

C:\>whos
Router [192.168.77.1]
                                  online

MailServer [192.168.77.16]
                                  online

Monolith [192.168.77.17]
                                  online

JANE-IN-THE-BOX [192.168.77.18]
                                  online

dodger [unbekannt]
                                 offline

fast-jack [unbekannt]
                                 offline

C:\>

EDIT: ü-probem behoben

 

Es kann nicht angezeigt werden, ob eine IP statisch oder dynamisch ist.

Gruß
Edgar